本篇內容介紹了“VBS怎么實現顯示當前標準時間”的有關知識，在實際案例的操作過程中，不少人都會遇到這樣的困境，接下來就讓小編帶領大家學習一下如何處理這些情況吧！希望大家仔細閱讀，能夠學有所成！

成都創新互聯公司服務項目包括瀘縣網站建設、瀘縣網站制作、瀘縣網頁制作以及瀘縣網絡營銷策劃等。多年來，我們專注于互聯網行業，利用自身積累的技術優勢、行業經驗、深度合作伙伴關系等，向廣大中小型企業、政府機構等提供互聯網行業的解決方案，瀘縣網站推廣取得了明顯的社會效益與經濟效益。目前，我們服務的客戶以成都為中心已經輻射到瀘縣省份的部分城市，未來相信會繼續擴大服務區域并繼續獲得客戶的支持與信任！

Option Explicit
 
Dim blnDate, blnTime
Dim dtmDate
Dim intDay, intFormat, intHour, intMin, intMonth, intSec, intUTC, intValid, intYear
Dim strISO
 
With WScript.Arguments
  ' Check command line arguments
  If .Unnamed.Count = 0 Then dtmDate = Now
  If .Unnamed.Count > 0 Then dtmDate = .Unnamed(0)
  If .Unnamed.Count > 1 Then dtmDate = dtmDate & " " & .Unnamed(1)
  If .Unnamed.Count > 2 Then dtmDate = dtmDate & " " & .Unnamed(2)
  If .Unnamed.Count > 3 Then Syntax
  On Error Resume Next
  dtmDate = CDate( dtmDate )
  If Err Then
    On Error Goto 0
    Syntax
  End If
  On Error Goto 0
  If Not IsDate( dtmDate ) Then Syntax
  intValid = 0
  blnDate = True
  blnTime = True
  If .Named.Exists( "D" ) Then
    blnDate = True
    blnTime = False
    intValid = intValid + 1
  End If
  If .Named.Exists( "T" ) Then
    blnDate = False
    blnTime = True
    intValid = intValid + 1
  End If
  If intValid <> .Named.Count Then Syntax
  If intValid > 1 Then Syntax
End With
 
' Format the output string
intYear = DatePartLZ( "yyyy", dtmDate )
intMonth = DatePartLZ( "m", dtmDate )
intDay  = DatePartLZ( "d", dtmDate )
intHour = DatePartLZ( "h", dtmDate )
intMin  = DatePartLZ( "n", dtmDate )
intSec  = DatePartLZ( "s", dtmDate )
If blnDate Then strISO = intYear & "-" & intMonth & "-" & intDay
If blnTime Then strISO = strISO & " " & intHour & ":" & intMin & ":" & intSec
' Display the result
WScript.Echo Trim( strISO )
 
 
Function DatePartLZ( myInterval, myDate )
  ' Add a leading zero to the DatePart() if necessary
  Dim strDatePart
  strDatePart = DatePart( myInterval, myDate )
  If Len( strDatePart ) < 2 Then strDatePart = "0" & strDatePart
  DatePartLZ = strDatePart
End Function
 
 
Sub Syntax
  WScript.Echo vbcrlf _
        & "Date2ISO.vbs, Version 1.02" _
        & vbCrLf _
        & "Convert any date/time to ISO date/time" _
        & vbCrLf & vbCrLf _
        & "Usage: CSCRIPT.EXE //NoLogo Date2ISO.vbs date [ time ] [ /D | /T ]" _
        & vbCrLf & vbCrLf _
        & "Where: ""date""  is the date to convert (default: current date/time)" _
        & vbCrLf _
        & "    ""time""  is the optional time to convert" _
        & vbCrLf _
        & "    /D    return date only (default: both date and time)" _
        & vbCrLf _
        & "    /T    return time only (/D and /T are mutually exclusive)" _
        & vbCrLf & vbCrLf _
        & "Note:  If the specified date is ambiguous, the current user's date" _
        & vbCrLf _
        & "    and time format is assumed." _
        & vbCrLf & vbCrLf _
        & "Written by Rob van der Woude" _
        & vbCrLf _
        & "http://www.robvanderwoude.com"
  WScript.Quit 1
End Sub

附上一段VBS校對系統時間的代碼給大家參考下

'VBS校準系統時間 BY BatMan 
Dim objXML, Url, Message 
Message = "恭喜你，本機時間非常準確無需校對！" 
Set objXML = CreateObject("MSXML2.XmlHttp") 
Url = "/tupian/20230522/error.html
objXML.open "GET", Url, False 
objXML.send() 
Do Until objXML.readyState = 4 : WScript.Sleep 200 : Loop 
Dim objStr, LocalDate 
objStr = objXML.responseText 
LocalDate = Now() 
Set objXML = Nothing 
Dim objREG, regNum 
Set objREG = New RegExp 
objREG.Global = True 
objREG.IgnoreCase = True 
objREG.Pattern = "window.baidu_time\((\d{13,})\)" 
regNum = Int(objREG.Execute(objStr)(0).Submatches(0)) /1000 
Dim OldDate, BJDate, Num, Num1 
OldDate = "1970-01-01 08:00:00" 
BJDate = DateAdd("s", regNum, OldDate) 
Num = DateDiff("s", LocalDate, BJDate) 
If Abs(Num) >=1 Then 
Dim DM, DT, TM, objSHELL 
DM = DateAdd("S", Num, Now()) 
DT = DateValue(DM) 
TM = TimeValue(DM) 
If InStr(Now, "午") Then 
Dim Arr, Arr1, h34 
Arr = Split(TM, " ") 
Arr1 = Split(Arr(1), ":") 
h34 = Arr1(0) 
If Arr(0) = "下午" Then 
h34 = h34 + 12 
Else 
If h34 = 12 Then h34 = 0 
End If 
TM = h34 & ":" & Arr1(1) & ":" & Arr1(2) 
End If 
Set objSHELL = CreateObject("Wscript.Shell") 
objSHELL.Run "cmd /cdate " & DT, False, True 
objSHELL.Run "cmd /ctime " & TM, False, True 
Num1 = Abs(DateDiff("s", Now(), BJDate)) 
Message = "【校準前】" & vbCrLf _ 
& "標準北京時間為：" & vbTab & BJDate & vbCrLf _ 
& "本機系統時間為：" & vbTab & LocalDate & vbCrLf _ 
& "與標準時間相差：" & vbTab & Abs(Num) & "秒" & vbCrLf & vbCrLf _ 
& "【校準后】" & vbCrLf _ 
& "本機系統時間為：" & vbTab & Now() & vbCrLf _ 
& "與標準時間相差：" & vbTab & Num1 & "秒" 
Set objSHELL = Nothing 
End If 
WScript.Echo Message

“VBS怎么實現顯示當前標準時間”的內容就介紹到這里了，感謝大家的閱讀。如果想了解更多行業相關的知識可以關注創新互聯網站，小編將為大家輸出更多高質量的實用文章！

當前名稱：VBS怎么實現顯示當前標準時間-創新互聯
當前路徑：http://vcdvsql.cn/article42/cesjec.html

成都網站建設公司_創新互聯，為您提供商城網站、企業網站制作、自適應網站、搜索引擎優化、網站改版、品牌網站設計

廣告

聲明：本網站發布的內容（圖片、視頻和文字）以用戶投稿、用戶轉載內容為主，如果涉及侵權請盡快告知，我們將會在第一時間刪除。文章觀點不代表本網站立場，如需處理請聯系客服。電話：028-86922220；郵箱：631063699@qq.com。內容未經允許不得轉載，或轉載時需注明來源： 創新互聯