如何統一one.asp多項目、函數庫、類庫的版本？相信很多沒有經驗的人對此束手無策，為此本文總結了問題出現的原因和解決方法，通過這篇文章希望你能解決這個問題。

成都創新互聯客戶idc服務中心，提供成都移動機房托管、成都服務器、成都主機托管、成都雙線服務器等業務的一站式服務。通過各地的服務中心，我們向成都用戶提供優質廉價的產品以及開放、透明、穩定、高性價比的服務，資深網絡工程師在機房提供7*24小時標準級技術保障。

舉個簡單的應用場景，開發一個小的API系統，支持 XML、JSON輸出。區別是 基礎版（dev/dev.asp）只支持 Access，VIP版本（dev/vip.asp）支持 Access + SQL Server。這樣VIP版本就需要在現在的基礎上 增加 sqlserver的支持，增加額外的 配置項。開發過程只需要 按正常開發即可。

開發完畢后，通過 one.asp 打包成 index.asp 和 vip.asp 兩個版本，整套程序都是一個獨立的文件。

下圖演示了 解析過程：

完整的測試代碼 可以 訪問：oneasp.rar 下載

核心代碼 如下：

' ====================================================
' 類名：One
' 作者：mqycn
' 博客：http://www.miaoqiyuan.cn
' 源碼：http://www.miaoqiyuan.cn/p/one-php
' 說明：多項目 函數庫、類庫 統一為一個版本的方法
' ====================================================
Class OneAsp
  Private FSO
  Private Root
   
  Private Sub Class_Initialize()
    Set FSO = Server.CreateObject("Scripting.FileSystemObject")
  End Sub
   
  Private Sub Class_Terminate()
    Set FSO = Nothing
  End Sub
   
  Public Function Run(ByVal sourceFile, ByVal saveFile)
    Run = "<hr><b>Input:</b>" & sourceFile & "<br><b>Result:</b>" & Save(saveFile, Include(sourceFile))
  End Function
   
   
  Public Function Include(ByVal path)
    Dim tmpPath, tmpItem, arrPath, index
    tmpPath = ""
    arrPath = Split(path, "/")
    For index = 0 To UBound(arrPath) - 1
      tmpItem = arrPath(index)
      tmpPath = tmpPath & tmpItem & "/"
    Next
    Include = Parse(tmpPath, arrPath(UBound(arrPath)))
  End Function
   
  Private Function Parse(ByVal root, ByVal fileName)
    Call SetRoot(root)
    Dim html
    html = OpenRead(fileName)
     
    Dim preg, pregResult
    Set preg = New Regexp
    preg.pattern = "<!--#include file=""([^""]*)""-->"
    preg.global = True
    preg.ignorecase = True
     
    Dim htmlInclude
    Set pregResult = preg.execute(html)
    For Each htmlInclude In pregResult
      html = Replace(html, htmlInclude, Include(root & htmlInclude.submatches(0)))
    Next
     
    Parse = "<% '" & root & fileName & " Start %" & ">" & vbCrLf & html & vbCrLf & "<%  '" & root & fileName & " End %" & ">" & vbCrLf
  End Function
   
  Private Function SetRoot(ByVal rootPath)
    If Right(rootPath, 1) <> "/" Then rootPath = rootPath & "/"
    Root = rootPath
  End Function
   
  Private Function RealPath(ByVal path)
    RealPath = Server.Mappath(Root & path)
  End Function
   
  Private Function OpenRead(ByVal path)
    Dim txtFile
    Set txtFile = FSO.OpenTextFile(RealPath(path))
    OpenRead = txtFile.ReadAll()
    txtFile.close
    On Error GoTo 0
  End Function
   
  Public Function Save(ByVal path, ByVal body)
    Dim txtFile
    Set txtFile = FSO.CreateTextFile(Server.Mappath(path))
    txtFile.write body
    txtFile.close
    Set txtFile = Nothing
    Save = path
  End Function
   
End Class

標題名稱：如何統一one.asp多項目、函數庫、類庫的版本-創新互聯
文章源于：http://vcdvsql.cn/article42/gishc.html

成都網站建設公司_創新互聯，為您提供網站收錄、云服務器、面包屑導航、自適應網站、微信小程序、定制網站

廣告

聲明：本網站發布的內容（圖片、視頻和文字）以用戶投稿、用戶轉載內容為主，如果涉及侵權請盡快告知，我們將會在第一時間刪除。文章觀點不代表本網站立場，如需處理請聯系客服。電話：028-86922220；郵箱：631063699@qq.com。內容未經允許不得轉載，或轉載時需注明來源： 創新互聯